Сравнение: delay() против millis() в ESP32.

Микроконтроллер ESP32, благодаря своей производительности и встроенным модулям Wi-Fi и Bluetooth, стал популярной платформой для разработки проектов Интернета вещей (IoT) и встраиваемых систем. Одной из первых задач, с которой сталкиваются начинающие разработчики, является управление светодиодом – классическая программа "Blink". Простейший способ – использовать функцию delay(). Однако она полностью блокирует выполнение программы на заданное время. Для простых задач это приемлемо, но если нужно одновременно выполнять другие операции (опрашивать датчики, проверять кнопки, обмениваться данными по сети), delay() становится непригодной.

Данный урок демонстрирует, как реализовать выполнение нескольких задач псевдопараллельно на ESP32, избегая delay(). В качестве примера рассмотрим мигание светодиодом с одновременной проверкой состояния кнопки, используя неблокирующий подход на основе функции millis().

Мы рассмотрим и сравним три подхода:

1. Мигание светодиодом с использованием delay().
2. Мигание светодиодом с использованием millis().
3. Добавление дополнительных задач.

Описанный метод применим не только к светодиодам, но и к любым задачам, требующим выполнения действий через определенные интервалы без блокировки основного цикла.

Примечание: Это руководство посвящено программированию ESP32 на Arduino (C/C++) через Arduino IDE. Если вы предпочитаете MicroPython, обратитесь к руководству: ESP32 MicroPython - LED - Blink.

Компоненты.

Основы работы со светодиодом и кнопкой.

Есть отдельные руководства по светодиодам и кнопкам. Они содержат подробную информацию о распиновке, принципах работы, схемах подключения и примерах кода.

Схема подключения.

На схеме ниже показано подключение светодиода (через резистор) и кнопки к пинам GPIO ESP32. Кнопка подключена к GND и пину GPIO с внутренним подтягивающим резистором (INPUT_PULLUP).

Сравнение подходов: delay() против millis().

Рассмотрим два варианта кода для мигания светодиодом и проверки состояния кнопки.

Код ESP32 - Использование delay() (Блокирующий подход)

/*
 *  Сравнение: delay() против millis() в ESP32.
 *  https://arduino-tex.ru/news/209/sravnenie-delay-protiv-millis-v-esp32.html
 */
#define LED_PIN 21           // Пин GPIO21 ESP32, подключенный к светодиоду
#define BUTTON_PIN 18        // Пин GPIO18 ESP32, подключенный к кнопке
#define BLINK_INTERVAL 1000  // Интервал мигания светодиода (миллисекунды)
// Переменные:
int ledState = LOW;              // Текущее состояние светодиода (LOW - выключен)
int previousButtonState = HIGH;  // Предыдущее состояние кнопки (HIGH, т.к. INPUT_PULLUP)
void setup() {
  Serial.begin(115200);      // Инициализация последовательного порта
  pinMode(LED_PIN, OUTPUT);  // Пин светодиода как выход
  // Пин кнопки как вход с подтягивающим резистором:
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  previousButtonState = digitalRead(BUTTON_PIN);  // Начальное состояние кнопки
}
void loop() {
  // Инвертируем состояние светодиода:
  ledState = (ledState == LOW) ? HIGH : LOW;
  digitalWrite(LED_PIN, ledState);  // Установить новое состояние
  // !!! КРИТИЧЕСКИЙ МОМЕНТ: Ожидание BLINK_INTERVAL миллисекунд !!!
  delay(BLINK_INTERVAL);  // ESP32 НЕ МОЖЕТ выполнять другие действия
  // Проверка состояния кнопки
  int currentButtonState = digitalRead(BUTTON_PIN);
  if (currentButtonState != previousButtonState) {
    Serial.println(currentButtonState);        // Вывод состояния
    previousButtonState = currentButtonState;  // Сохранить состояние
  }
  // ЗДЕСЬ МОГЛИ БЫ БЫТЬ ДРУГИЕ ОПЕРАЦИИ, но они выполняются реже из-за delay()
}

Краткие инструкции:

1. Настройте Arduino IDE для ESP32.
2. Соберите схему.
3. Подключите ESP32 к ПК.
4. Откройте Arduino IDE.
5. Выберите плату ESP32 и COM-порт.
6. Скопируйте код.
7. Скомпилируйте и загрузите код.
8. Откройте монитор порта (115200 бод).
9. Нажмите кнопку 4 раза.
10. Наблюдайте за светодиодом и за информацию в мониторе порта (Serial Monitor).

Ожидаемый результат delay():

(Не все нажатия будут зарегистрированы)

Во время delay(BLINK_INTERVAL) ESP32 не выполняет цикл loop(). Нажатия в этот интервал не будут обнаружены.

Код ESP32 - Без delay() (Использование millis(), Неблокирующий подход).

/*
 *  Сравнение: delay() против millis() в ESP32.
 *  https://arduino-tex.ru/news/209/sravnenie-delay-protiv-millis-v-esp32.html
 */
#define LED_PIN 21           // Пин GPIO21 ESP32, подключенный к светодиоду
#define BUTTON_PIN 18        // Пин GPIO18 ESP32, подключенный к кнопке
#define BLINK_INTERVAL 1000  // Интервал мигания светодиода (миллисекунды)
// Переменные:
int ledState = LOW;                // Текущее состояние светодиода
int previousButtonState = HIGH;    // Предыдущее состояние кнопки
unsigned long previousMillis = 0;  // Время последнего изменения светодиода
void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  previousButtonState = digitalRead(BUTTON_PIN);  // Начальное состояние
}
void loop() {
  unsigned long currentMillis = millis();  // Текущее время
  // Проверяем, прошло ли достаточно времени:
  if (currentMillis - previousMillis >= BLINK_INTERVAL) {
    // Инвертируем состояние:
    ledState = (ledState == LOW) ? HIGH : LOW;
    digitalWrite(LED_PIN, ledState);
    previousMillis = currentMillis;  // Сохраняем время
  }
  // --- Проверка состояния кнопки ---  (выполняется в КАЖДОЙ итерации)
  int currentButtonState = digitalRead(BUTTON_PIN);
  if (currentButtonState != previousButtonState) {
    Serial.println(currentButtonState);
    previousButtonState = currentButtonState;
  }
  // --- ЗДЕСЬ МОЖНО ДОБАВИТЬ ДРУГИЕ НЕБЛОКИРУЮЩИЕ ЗАДАЧИ ---
}

Объяснение millis():

millis() возвращает миллисекунды с момента запуска ESP32.

• Сохраняем время последнего события в previousMillis.
• В loop() получаем текущее время: currentMillis = millis();.
• Вычисляем разницу: currentMillis - previousMillis.
• Если разница >= BLINK_INTERVAL, выполняем действие.
• Обновляем previousMillis = currentMillis;.

Цикл loop() выполняется быстро, позволяя другим частям кода выполняться почти непрерывно.

Краткие инструкции (millis()):

1. Настройте Arduino IDE и соберите схему.
2. Скопируйте, скомпилируйте и загрузите код.
3. Откройте монитор порта (115200).
4. Нажмите кнопку 4 раза.
5. Наблюдайте за светодиодом и за информацию в мониторе порта (Serial Monitor).

Ожидаемый результат millis():

(Все нажатия зарегистрированы)

Данный подход позволяет ESP32 управлять светодиодом и реагировать на события.

Построчное объяснение кода.

Комментарии в коде содержат детальные объяснения.

Добавление дополнительных задач.

Используя millis(), можно управлять несколькими задачами. Пример с двумя светодиодами (1000 мс и 500 мс) и кнопкой.

Схема подключения - два светодиода.

Подключите второй светодиод (с резистором) к GPIO22.

/*
 *  Сравнение: delay() против millis() в ESP32.
 *  https://arduino-tex.ru/news/209/sravnenie-delay-protiv-millis-v-esp32.html
 */
#define LED_PIN_1 22           // Пин GPIO22, Светодиод 1
#define LED_PIN_2 21           // Пин GPIO21, Светодиод 2
#define BUTTON_PIN 18          // Пин GPIO18, кнопка
#define BLINK_INTERVAL_1 1000  // Интервал Светодиода 1 (мс)
#define BLINK_INTERVAL_2 500   // Интервал Светодиода 2 (мс)
// Переменные для Светодиода 1:
int ledState_1 = LOW;
unsigned long previousMillis_1 = 0;
// Переменные для Светодиода 2:
int ledState_2 = LOW;
unsigned long previousMillis_2 = 0;
// Переменные для кнопки:
int previousButtonState = HIGH;
void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN_1, OUTPUT);
  pinMode(LED_PIN_2, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  previousButtonState = digitalRead(BUTTON_PIN);
}
void loop() {
  unsigned long currentMillis = millis();  // Текущее время
  // --- Управление Светодиодом 1 ---
  if (currentMillis - previousMillis_1 >= BLINK_INTERVAL_1) {
    ledState_1 = (ledState_1 == LOW) ? HIGH : LOW;
    digitalWrite(LED_PIN_1, ledState_1);
    previousMillis_1 = currentMillis;  // Обновляем время
  }
  // --- Управление Светодиодом 2 ---
  if (currentMillis - previousMillis_2 >= BLINK_INTERVAL_2) {
    ledState_2 = (ledState_2 == LOW) ? HIGH : LOW;
    digitalWrite(LED_PIN_2, ledState_2);
    previousMillis_2 = currentMillis;  // Обновляем время
  }
  // --- Проверка состояния кнопки ---
  int currentButtonState = digitalRead(BUTTON_PIN);
  if (currentButtonState != previousButtonState) {
    Serial.println(currentButtonState);
    previousButtonState = currentButtonState;
  }
  // --- ЗДЕСЬ МОЖНО ДОБАВИТЬ ЕЩЕ ЗАДАЧ ---
}

Пояснение: Для каждого светодиода свой набор переменных. Цикл loop() выполняется быстро, создавая псевдо-многозадачность.

Заключение.

Мы рассмотрели проблему delay() и показали альтернативу – millis(). delay() останавливает программу, а millis() позволяет проверять интервалы без остановки.

Преимущества millis():

• Отзывчивость: Быстрая реакция на события.
• Псевдо-многозадачность: Несколько действий в одном цикле.
• Масштабируемость: Легко добавлять задачи.

Освонова с millis() – ключевой шаг для сложных проектов на ESP32. Этот паттерн широко применяется при работе с сенсорами, сетевыми протоколами и интерфейсами.

Дополнительная информация к данному уроку:

• Пошаговая установка плат ESP32 в Arduino IDE 2 для Windows, Mac OS и Linux.
• Программирование ESP32 в среде Arduino IDE. Структура кода
• ESP32: Простой скетч в Arduino IDE
• Распиновка ESP32, какие контакты GPIO можно использовать, а какие нет?
• Справочник языка Ардуино
• ESP32: Управление вводом с помощью кнопок. Типы, схемы, код.
• ESP32 Arduino IDE. Подавление дребезга контактов кнопки.

Понравился урок: Сравнение: delay() против millis() в ESP32? Не забудь поделиться с друзьями в соц. сетях.

А также подписаться на наш канал на YouTube, вступить в группу Вконтакте, в Telegram.

Спасибо за внимание!

Технологии начинаются с простого!

Фотографии к статье

 

 

 

 

 

 

Файлы для скачивания

	Код - Мигание светодиодом с использованием delay().ino	2 Kb	24	Скачать Вы можете скачать файл.
	Код - Мигание светодиодом с использованием millis().ino	2 Kb	19	Скачать Вы можете скачать файл.
	Код 3 - Добавление дополнительных задач .ino	2 Kb	18	Скачать Вы можете скачать файл.